太陽光発電パネルの反射光の方向

フリーソフトの十進Basicで計算しています。自由にお使いください。尚、間違いがあっても容赦してください。前提は、地球は球で公転は円軌道、パネルは十分小さい。

表示しているグラフは北緯35度、パネル架台の地表面からの角をfとしてtan(f)=0.4（一般的な屋根の傾斜角です）としています。

架台の向きは真南から東向きを正としてその角をhで表し、ｈ＝０°、３０°、６０°、９０°、１８０°の場合を表示しています。

グラフの見方

反射光の天球に対する位置を表示します。円が地平線、真ん中が天頂です。天頂からある点の方向は実際の反射光の方向になります。天頂からある点までの距離は反射光と鉛直線の角を表します。（比例します）

７本の点線は、左端が夏至、右端が冬至、残りは半年を６等分して１ヶ月ごとの反射光の方向を表します。点は１０分ごとにプロットします。

例えば、真ん中の点線は、春分と秋分の日ですが日の出の時、反射光は真西の地平です。

夏至の日の反射光は一番左の点線です。地平線の下の場合もあります。

反射光の地平線からの角をgとするとき、sin(g)＜-0.2のときは表示しません。

反射光が地平に近いか地平より下のとき、深刻な問題が生じる場合が多いです。反射光が地平から十分に上の場合は問題はありません。

架台の方向　h=0°（真南）

ｈ＝３０°

h=６０°

ｈ＝９０°（真東）

h=１８０°（真北）

参考までにBasicのプログラムを書いておきます。

パネルの南からの角（東向きを正の角とする（度で））、緯度（度で）をそれぞれ求めに応じて入力します。

パネルの水平に対する傾斜角は　INPUT PROMPTの下の行でf1の値で設定します。傾斜角のtanです。初期設定はtanθ=0.4です。

１０進Basicのプログラム、この下の行からENDの上の行までコピーしてBasicのプログラムのエリアに貼り付けて実行して下さい。

REM a:緯度 b:地軸と公転軸の傾き c:最小南中角　d:最大南中角

REM f1:パネルの法線ベクトルと鉛直線のなす角(tanの値)　h1:パネルの方向と南のなす角(度),東を+

REM ex,ey,ezはパネルの法線方向の単位ベクトルの成分

SET WINDOW -1.1,1.1,-1.1,1.1

DRAW circle

PLOT LINES:-1,0;1,0

PLOT LINES:0,-1;0,1

PLOT TEXT ,AT 0,-1:"東"

PLOT TEXT ,AT 0,1:"西"

PLOT TEXT ,AT 1,0:"北"

PLOT TEXT ,AT -1,0:"南"

PLOT TEXT ,AT 0,0:"天頂"

PLOT TEXT ,AT -0.71,-0.71:"地平"

INPUT PROMPT "パネルの向き南からの東向きへの角(度)=":h1

INPUT PROMPT "緯度(度)=":a1

LET f1=0.4

LET b1=23.4

LET c1=90-(a1+b1)

LET d1=90-(a1-b1)

LET a=a1*PI/180

LET b=b1*PI/180

LET c=c1*PI/180

LET d=d1*PI/180

LET f=atn(f1)

LET h=h1*PI/180

LET ex=SIN(f)*SIN(h)

LET ey=-SIN(f)*COS(h)

LET ez=COS(f)

FOR i=0 TO 6 STEP 1

LET r=(c+d)/2+ASIN(COS(PI/6*i)*SIN(b))

IF i=5 THEN 20

LET j=i+1

GOTO 30

20 LET j=12

30 SET POINT COLOR j

40 FOR s=0 TO 2*PI STEP PI/72

LET p=SIN(a+r)*COS(s)

LET q=SIN(a+r)*SIN(s)*SIN(a)-COS(a)*COS(a+r)

LET rr=-SIN(a+r)*SIN(s)*COS(a)-COS(a+r)*SIN(a)

IF rr<-0.001 THEN 10

LET ep=ex*p+ey*q+ez*rr

LET sx=ep*ex

LET sy=ep*ey

LET sz=ep*ez

LET qx=2*sx-p

LET qy=2*sy-q

LET qz=2*sz-rr

IF qz<-0.2 THEN 10

REM LET t=(1-qz)/sqr(qx^2+qy^2)

LET t=(1-2/PI*ASIN(qz))/SQR(qx^2+qy^2)

LET tx=qy*t

LET ty=-qx*t

PLOT POINTS:tx,ty

10 NEXT s

NEXT i

END